//////////////////////////////////////////////////////////////////
// This code shows that all Number Fields unramified away from
// {2,3} are two torsion fields of elliptic curves.
//
// This computations are relevant for the `level lowering at 2'
// remark the paper "Primitive Integral Solutions to x^2 + y^3
// = z^{10}' by David Brown
//
// Computations were done using Magma, version V2.13-6
//////////////////////////////////////////////////////////////////

P<x> := PolynomialRing(Rationals());


//////////////////////////////////////////////////////////////////
// Computed the following using sage
// J = JonesDatabase()
// J.unramified_outside([2,3])
//////////////////////////////////////////////////////////////////
f := [x^3 - 3*x + 1, x^3 - 2, x^3 + 3*x - 2, x^3 - 3, x^3 - 3*x - 4, x^3 - 3*x - 10, x^3 - 12, x^3 - 6, x^3 - 9*x - 6];
K := [NumberField(g) : g in f];

//////////////////////////////////////////////////////////////////
// This gets all elliptic curves of conductor dividing 12^3
//////////////////////////////////////////////////////////////////

D := CremonaDatabase();
e := {@@};
for a in [0..3] do
  for b in [0..6] do
    e := e join {@E : E in EllipticCurves(D,2^a*3^b)@};
  end for;
end for;

g := {@ HyperellipticPolynomials( WeierstrassModel(E)) : E in e@};;


//////////////////////////////////////////////////////////////////
// For each number field k in K, this searches for an elliptic
// curve with two torsion field isomorphic to k
//
// (It returns that all 9 k in K are two torsion fields.)
//////////////////////////////////////////////////////////////////

K_low := [k : k in K | exists{f : f in g | IsIrreducible(f) and  IsIsomorphic(k,NumberField(f))}];


//////////////////////////////////////////////////////////////////
// This picks out a single E for each k in K
//////////////////////////////////////////////////////////////////

pairs := {@@};
for k in K do
        bool := exists(t){f : f in g | IsIrreducible(f) and  IsIsomorphic(k,NumberField(f))};
        pairs := pairs join {<k,t>};
end for;